Classe ContentControlListEntry (Word VBA)

Um objeto ContentControlListEntry representa um item da lista em uma lista suspensa lista ou combinação caixa controle de conteúdo. Um objeto ContentControlListEntry é um membro da coleção ContentControlListEntries para um objeto ContentControl. Para usar uma variável de classe ContentControlListEntry, ela primeiro precisa ser instanciada por exemplo

Dim ccl as ContentControlListEntry
Set ccl = ActiveDocument.Range.ContentControls(1).DropdownListEntries(Index:=1)

For Each

Aqui está um exemplo de processamento dos itens ContentControlListEntry em uma coleção.

Dim cclListEntry As ContentControlListEntry
For Each cclListEntry In ActiveDocument.Range.ContentControls(1).DropdownListEntries
	If cclListEntry.Text = "Other" Then cclListEntry.Delete
Next cclDropdownListEntry

Delete

Exclui o item especificado de um controle de conteúdo de lista suspensa ou caixa de combinação.

Dim objCC As ContentControl 
Dim objCL As ContentControlListEntry 
 
For Each objCC In ActiveDocument.ContentControls 
 If objCC.Type = wdContentControlComboBox Or _ 
 objCC.Type = wdContentControlDropdownList Then 
 For Each objCL In objCC.DropdownListEntries 
 If objCL.Text = "Other" Then objCL.Delete 
 Next 
 End If 
Next 
 

Index

Retorna ou define um valor Long que representa a posição ordinal de um item de lista de controle de conteúdo na coleção de itens de lista. Leitura/gravação.

Você pode definir a propriedade Index para qualquer valor numérico para alterar a posição ordinal de um item em uma lista. Por exemplo, se você alterar a propriedade de índice para o quinto item em uma lista para "2", o quinto item se torna o segundo item. O segundo item original e todos os itens que são seguem, movem uma posição para baixo.

ActiveDocument.Range.ContentControls(1).DropdownListEntries(1).Index =

MoveDown

Move um item em um controle de conteúdo de caixa de combinação ou lista suspensa um item para baixo, de forma que ele fique após o item que originalmente o seguia.

Dim objCC As ContentControl 
Dim objCL As ContentControlListEntry 
Dim intCount As Integer 
 
Set objCC = ActiveDocument.ContentControls.Item(3) 
 
If objCC.Type = wdContentControlComboBox Or _ 
 objCC.Type = wdContentControlDropdownList Then 
 
 Set objCL = objCC.DropdownListEntries.Item(1) 
 
 For intCount = 1 To objCC.DropdownListEntries.Count 
 objCL.MoveDown 
 Next 
 
End If

MoveUp

Move um item em um controle de conteúdo de caixa de combinação ou lista suspensa um item para cima, de forma que ele fique antes do item que originalmente o precedia.

Dim objCC As ContentControl 
Dim objCL As ContentControlListEntry 
Dim intCount As Integer 
 
Set objCC = ActiveDocument.ContentControls.Item(3) 
 
If objCC.Type = wdContentControlComboBox Or _ 
 objCC.Type = wdContentControlDropdownList Then 
 
 Set objCL = objCC.DropdownListEntries.Item(objCC.DropdownListEntries.Count) 
 
 For intCount = 1 To objCC.DropdownListEntries.Count 
 objCL.MoveUp 
 Next 
 
End If

Select

Seleciona a entrada de lista em um controle de conteúdo de caixa de combinação ou lista suspensa e define o texto do controle de conteúdo com o valor do item.

Dim objCC As ContentControl 
Dim objCE As ContentControlListEntry 
Dim objMap As XMLMapping 
 
Set objCC = ActiveDocument.ContentControls.Add(wdContentControlDropdownList) 
objCC.Title = "My Favorite Animal" 
If objCC.ShowingPlaceholderText Then _ 
 objCC.SetPlaceholderText , , "Select your favorite animal " 
 
'List entries 
objCC.DropdownListEntries.Add "Cat" 
objCC.DropdownListEntries.Add "Dog" 
objCC.DropdownListEntries.Add "Horse" 
objCC.DropdownListEntries.Add "Monkey" 
objCC.DropdownListEntries.Add "Snake" 
 
Set objCE = objCC.DropdownListEntries.Add("Other") 
objCE.Select

Text

Retorna ou define um String que representa o texto de exibição de um item de lista para um controle de conteúdo de caixa de combinação ou lista suspensa. Leitura/gravação.

Entradas da lista devem ter nomes para exibição exclusivos. Tentando alterar a propriedade Text para uma cadeia de caracteres que já existe na lista de entradas gera um erro em tempo de execução.

Dim objCC As ContentControl 
Dim objLE As ContentControlListEntry 
Dim strFirst As String 
 
For Each objCC In ActiveDocument.ContentControls 
 If objCC.Type = wdContentControlComboBox Or objCC.Type = wdContentControlDropdownList Then 
 For Each objLE In objCC.DropdownListEntries 
 strFirst = Left(objLE.Text, 1) 
 
 If strFirst = LCase(strFirst) Then 
 objLE.Text = UCase(strFirst) & Right(objLe.Text, Len(objLe.Text) - 1) 
 End If 
 Next 
 End If 
Next

Value

Retorna ou define um String que representa o valor de programação de um item em um controle de conteúdo de caixa de combinação ou lista suspensa. Leitura/gravação.

Use a propriedade Value para armazenar os dados que você precisa usar ao tempo de processamento. Por exemplo, a propriedade Text pode conter uma cadeia de caracteres que você deseja exibir e a propriedade Value pode conter um número, como um número de item, que você pode usar para procurar as informações em um banco de dados. Além disso, o valor da propriedade Value é o que é enviado para os dados XML personalizados, se o controle de conteúdo seja mapeado para dados XML no repositório de dados.

Dim objCc As ContentControl 
Dim objLe As ContentControlListEntry 
Dim strText As String 
Dim strChar As String 
 
Set objCc = ActiveDocument.ContentControls(3) 
 
For Each objLE In objCC.DropdownListEntries 
 If objLE.Text <> "Other" Then 
 strText = objLE.Text 
 objLE.Value = "My favorite animal is the " & strText & "." 
 End If 
Next